\ కాంవేది జీవితము ఆట 
\ రచయిత : లీఓ వాన్గ్  ( ఈ ప్రోగ్రాం ఆకరిలో చూడండి )
\ అనువాదకుడు : మైనేని కృష్ణ
\ 30 నవంబరు 2019

include ans-words
include mlp-telugu
చేర్చు strings
చేర్చు ansi

: అక్కడ  ( col row -- ) AT-XY ;
: పేజీ  ( -- ) PAGE ;
: అక్షరాలు ;

\ ఈ జీవితం ఉంచు
1 అక్షరాలు మారదు  /అక్షరము
: C+!  ( char c-addr -- )  డూప్  >r  c@ +  r> c! ;

\ ప్రపంచం క్రమము
25 మారదు  ఎంత-లోతు
80 మారదు  ఎంత-వెడల్పు 
ఎంత-వెడల్పు ఎంత-లోతు *  1-   \ 1- నా స్క్రీను మీద  స్క్రోల్ల్ అవ్వకుండా చేయడానికి
   మారదు ఇళ్ళు

\ వ్రపంచం తయారుచేయడానికి
: వ్రపంచం 
   సృజించు  ( -- )  ఇళ్ళు అక్షరాలు ఉంచు
    చేస్తుంది  ( u -- c-addr )  మార్చు ఇళ్ళు +  ఇళ్ళు  మిగత అక్షరాలు + ;

వ్రపంచం  పాత 
వ్రపంచం  కొత్త

\ జీవ గణనలు

\ మొదల పెట్టు hexadecimal గణన
HEX  \ hex xy : x జీవము పట్టుతోంది , y పక్కవాళ్ళు లెక్క పట్టుతోంది

10 మారదు బతికున్నాయి  \ 0y సమానం జీవము లేదు

\ కాంవే నియమాలు:
\ ఒక జీవితం పక్కవాళ్ళు మీద ఆధారపడుతోంది

\ రెండు పక్కవాళ్ళుకన్నా తక్కువ ఉంటే చనిపోతుంది
: ఒంటరి  ( char -- flag )  12 తక్కువ ;

\ ముగ్గురు పక్కవాళ్ళుకన్నా ఎక్కువ ఉంటే చనిపోతుంది
: ఇరుకు  ( char -- flag )  13 ఎక్కువ  ;

: -భరించుకునే  ( char -- flag )
    డూప్  ఒంటరి  మార్చు ఇరుకు  కాని ;

\ ముగ్గురు వక్కవాళ్ళు సమానం ఉన్నారో ఒక జీవితం పుట్టుతోంది
: ఉద్దీపనము  ( char -- flag )  03 సమానం ;

\ మళ్ళీ decimal
DECIMAL

\ compass దిక్కులు
: ఉ  ( i -- j )  ఎంత-వెడల్పు  - ;
: ద  ( i -- j )  ఎంత-వెడల్పు  + ;
: తూ  ( i -- j )  1+ ;
: ప  ( i -- j )  1- ;

\ జనాభ లెక్క
: ఇల్లు+!  ( -1|1 i -- )  >r  బతికున్నాయి *  r> కొత్త C+! ;

: పక్కవాళ్ళు+!  ( -1|0|1 i -- )
   2డూప్ ఉ  ప కొత్త  C+!  2డూప్ ఉ కొత్త  C+!    2డూప్ ఉ తూ కొత్త  C+!
   2డూప్     ప కొత్త  C+!  (     i      )  2డూప్    తూ కొత్త  C+!
   2డూప్ ద  ప కొత్త  C+!  2డూప్  ద  కొత్త  C+!       ద  తూ కొత్త  C+! ;

: అవసరమైన-లెక్కలు-శాఖ ( -1|1 i -- )
   2డూప్  ఇల్లు+! పక్కవాళ్ళు+! ;

\ మర్త్య జీవితము
అక్షర ? మారదు ఆత్మ
  BL మారదు శరీరం

\ ఇంట్లో ఉన్నాము
: ఇల్లు  ( char i -- )  ఎంత-వెడల్పు /మిగత అక్కడ  ఎమిట్ ;

\ మార్పులు, మార్పులు
: పుట్టాడు  ( i -- )
   ఆత్మ మీద ఇల్లు
   1 మార్చు అవసరమైన-లెక్కలు-శాఖ ;
: చనిపోయాడు  ( i -- )
   శరీరం మీద ఇల్లు
   -1 మార్చు అవసరమైన-లెక్కలు-శాఖ ;

\ ఒక జీవితం మరియు అందరు జీవితాలు
: ఒకడు  ( c-addr -- i )
   0 పాత -  /అక్షరము  / ;
: అందరూ  ( -- )
   0 పాత  ఇళ్ళు
   మొదలు  డూప్
   అయితే  మీద c@  డూప్ బతికున్నాయి మరియు
  ఉంటే   -భరించుకునే  ఉంటే  మీద ఒకడు చనిపోయాడు   అప్పుడు
  కాదంటే  ఉద్దీపనము ఉంటే  మీద ఒకడు పుట్టాడు   అప్పుడు 
  అప్పుడు
 1 /string
   ఇంకొసారి  2పారేయి
   ఎంత-వెడల్పు 1- ఎంత-లోతు 1- అక్కడ ;

\ మొత్తమొదటి 
: శూన్యము  ( -- )  0 పాత  ఇళ్ళు ఖాళీ ;

\ ఆత్మ గొంతు
: గొంతు  ( -- c-addr u )
   పేజీ  ." చెప్పు: "  0 కొత్త  డూప్ ఇళ్ళు తీసుకొ ;

\ తెలివితేటలు
: పాము  ( -- )
   0 2 అక్కడ  ." జ్ఞానంకోసం కీ నొక్కు."  కీ పారేయి
   0 2 అక్కడ  ." మొదలు నించి చూడటానికి space నొక్కు, జీవితం బయట రాటానికి Esc నొక్కు." ;

\ మొదటి పరిస్థితి
: అమాయకం  ( -- )
   ఇళ్ళు 0
   చెయ్యి  ఐ కొత్త  c@ బతికున్నాయి /  ఐ  పక్కవాళ్ళు+! తిరుగు ;

\ పిల్లలు తల్లిదండ్రులు అయ్యారు
: ఎదుగారు  ( -- )  0 కొత్త  0 పాత  ఇళ్ళు  cmove ;

\ ఒక తోట
: స్వర్గము  ( c-addr u -- )
 >r  ఎంత-లోతు ఎంత-వెడల్పు *  
   ఎంత-లోతు 2 మిగత 0=  ఎంత-వెడల్పు మరియు -
 r@  -  2/  పాత
 r>  cmove
   0 పాత  ఇళ్ళు 0
    చెయ్యి  లెక్క శరీరం సమానం కాదు
       డూప్ ఉంటే  ఆత్మ  ఐ ఇల్లు  అప్పుడు
       బతికున్నాయి మరియు  ఐ కొత్త c!
   తిరుగు  పారేయి
   పాము
   అమాయకం ఎదుగారు ;

: సృష్టి  ( -- )  శూన్యము  గొంతు  స్వర్గము ;

\ మానవ లక్షణాలు

( 1000) 100 మారదు ఆలోచనలు
: ఉద్దేశాలు  ( -- )  ఆలోచనలు ms ;

( 1000) 100 మారదు చిత్రాలు
: ధ్యానం  ( -- )  చిత్రాలు ms ;

\ స్వేచ్ఛ
: క్రియ  ( -- char )
   కీ? డూప్ 
   ఉంటే  పారేయి  కీ
       డూప్ శరీరం సమానం ఉంటే  సృష్టి  అప్పుడు
   అప్పుడు ;

\ పరిస్థితి బట్టి
27 మారదు తప్పడము

\ చరిత్రము
: తిరుగుతుంది  ( -- )
   మొదలు  అందరూ ఎదుగారు
          ఉద్దేశాలు క్రియ ధ్యానం
          	తప్పడము సమానం వరకు ;

\ ఒక కల
: జీవితము  ( -- )  సృష్టి తిరుగుతుంది ;

జీవితము

\ 950724 + 970703 +

\ Copyright 1995 Leo Wong
\ hello@albany.net
\ http://www.albany.net/~hello/
